;jnc.bv
;2D difference 13C CT-HSQC
;for determination of J3(NC)
;in Val, Ile, and Thr residues
;for the determination of X1 angle
;Vuister, G.W., Wang, A.C., Bax, A.
;JACS 1993, 115, 5334-5335.
;Spectra are acquired as interleaved pairs of
;13C echo/antiecho pairs with 15N decoupled
;in first expt, and coupled in second expt
;
;Implemented and tested on DMX-600 by B. Volkman, 
;volkman@nmrfam.wisc.edu.  6/13/96 BFV
;
;Suitable grdprog and *.incl files are appended to
;the end of this pulse program, and should be removed and
;placed in appropriate /pp or /gp directory prior to execution
;of this pulse program.
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM or University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;BMRB Pulse Sequence Accession Number: 28
;
;use gradient program bvjnc_se(m) - follows pulse program
;adjust cnst30 to find magic angle (ca. 1.8) if equipped
;with 3-axis gradients

;**Set these parameters manually**
;F1= proton at H2O
;F2=15N at amides (~116ppm)
;F3=13C at Cg (~20.0ppm)
;F4=13C' SEDUCE (42.5ppm on NMRFAM DMX-600)
;p1 - 1H high power 90 @ pl1
;p2 - 15N high power 90 @ pl2
;p3 - 13C high power 90 @ pl3
;pcpd3 - 13C aliphatic decoupling 90 @ pl13
;cpdprg3 - waltz16
;pcpd4 - 13C' SEDUCE dec 90 @ sp4
;  300u @ 11.7 on NMRFAM DMX-600
;cpdprg4 - waltz16sel4 
;spnam4 - seduce1c6
;spoffs4 - 0 Hz
;
;p15=500u
;p17=500u
;p18=125u
;d0=3u
;IN0=1/SW*2 in carbon

;**The following parameters are preset**
#define SED_ON d13 cpds4:f4
#define SED_OFF d13 do:f4

"d2=1.7m"
"d4=0.85m"
"d5=500u"
"d6=p1"
"d7=p3"
"d8=28.6m"
"d9=10m"
"d11=100m"
"d12=10u"
"d13=5u"
"d16=300u"
"d0=3u"
"d18=d8-d16-p17+p2*2+d0*2"
"d22=d2-p15"
"d24=d4-p15"
"d25=d5-p18"
"d27=p2-p3"
"d28=p2-p1"
"d29=p3-p1"

#include <Avance.incl>
#include <Gradfa.incl>

;******start 1st expt - 15N not coupled to Cg *************

1 ze
  d9 pl1:f1 pl2:f2 pl3:f3 pl0:f4
2 d11 do:f3
  d9
3 d9
  d9*2
4 20u LOCKH_OFF
  d1 pl1:f1 pl3:f3
  (p1 ph0):f1
  d2 
  (d29 p1*2 ph0):f1 (p3*2 ph0):f3
  d2 LOCKH_ON
  (p1*55 ph0):f1
  (p1 ph1):f1
  GRADIENT15(cnst24)
  d16 cpds4:f4                                  ;13C' SEDUCE decoupling
  (p3 ph11):f3
  d13 
  (d8) (d0 d28 p1*2 ph0):f1 (d0 p2*2 ph15):f2  ;constant time evolution of 13C 
  (d18) (d0 d27 p3*2 ph13):f3
  d13 do:f4
  GRADIENT17(cnst25)
  d16 
  (p3 ph12):f3
  d6
  (p1 ph0):f1
  5u
  GRADIENT15(cnst21)
  d24
  (p3*2 ph0):f3
  (p1*2 ph0):f1 
  5u
  GRADIENT15(cnst21)
  d24
  d7
  (p3 ph1):f3
  (p1 ph1):f1 
  5u
  GRADIENT15(cnst21)
  d22 
  (d29 p1*2 ph0):f1 (p3*2 ph0):f3
  5u
  GRADIENT15(cnst21)
  d22
  (p1 ph0):f1
  d5
  (p1*2 ph0):f1
  GRADIENT18(cnst27)
  d25 pl13:f3
  go=2 ph31 cpd3:f3		
  d11 do:f3 wr #0 if #0 zd
  d9 ip12*2
  lo to 3 times 2		;loop for e/a pair

;******start 2nd expt - 15N coupled to Cg *************

6 d11 do:f3
  d9
7 20u LOCKH_OFF
  d1 pl1:f1 pl3:f3
  (p1 ph0):f1
  d2 
  (d29 p1*2 ph0):f1 (p3*2 ph0):f3
  d2 LOCKH_ON
  (p1*55 ph0):f1
  (p1 ph1):f1
  GRADIENT15(cnst24)
  d16 cpds4:f4                                  ;13C' SEDUCE decoupling
  (p3 ph11):f3
  d13 
  (d8) (d0 d28 p1*2 ph0):f1  			;constant time evolution of 13C 
  (d18) (d0 d27 p3*2 ph13):f3 (d0 p2*2 ph15):f2
  d13 do:f4
  GRADIENT17(cnst25)
  d16 
  (p3 ph12):f3
  d6
  (p1 ph0):f1
  5u
  GRADIENT15(cnst21)
  d24
  (p3*2 ph0):f3
  (p1*2 ph0):f1 
  5u
  GRADIENT15(cnst21)
  d24
  d7
  (p3 ph1):f3
  (p1 ph1):f1 
  5u
  GRADIENT15(cnst21)
  d22 
  (d29 p1*2 ph0):f1 (p3*2 ph0):f3
  5u
  GRADIENT15(cnst21)
  d22
  (p1 ph0):f1
  d5
  (p1*2 ph0):f1
  GRADIENT18(cnst27)
  d25 pl13:f3
  go=6 ph31 cpd3:f3
  d11 do:f3 wr #0 if #0 zd
  d9 ip12*2
  lo to 7 times 2		;loop for e/a pair
  d9 id0 
  d9 ip11*2 
  d9 ip31*2
  lo to 4 times l4		;loop to top for 13C evol
  20u LOCKH_OFF
exit
 

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0
ph13=1 1 3 3 2 2 0 0
ph15=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph31=0 2 0 2 2 0 2 0

***** Gradient Program - remove this and following
**** lines before executing pulse program
** bvjnc_sem.r ****

loop ns
{
p15 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p17 { (0)+(cnst25*cnst30) | (0) | (0)+(cnst25) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p18 { (0)+(cnst27*cnst30) | (0) | (0)+(cnst27) }
    { (0) | (0) | (0)          }
}
loop ns
{
p15 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p17 { (0)+(cnst25*cnst30) | (0) | (0)+(cnst25) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p18 { (0)+(cnst28*cnst30) | (0) | (0)+(cnst28) }
    { (0) | (0) | (0)          }
}

;Gradfa.incl  -  include file for Gradient Spectroscopy
;avance-version
;version 94/06/27

;
;#define GRADIENT15(ampl) p15:ngrad:c34
;#define GRADIENT16(ampl) p16:ngrad:c34
;#define GRADIENT17(ampl) p17:ngrad:c34
;#define GRADIENT18(ampl) p18:ngrad:c34
;#define GRADIENT19(ampl) p19:ngrad:c34
;#define GRADIENT20(ampl) p20:ngrad:c34


;#define BLKGRAD  setnmr2^0 setnmr0^34

;#define UNBLKGRAD setnmr2|0 setnmr0|34

;#define BLKGRAMP setnmr0^34

;#define UNBLKGRAMP setnmr0|34