;inv4prst
;MANUFACTURER: Bruker
;MODEL: DMX
;AUTHOR: Charles G. Hoogstraten
;DESCRIPTION: 2D H-1/X correlation via heteronuclear zero and double quantum
;   coherence
;phase sensitive using States-TPPI method
;BMRB Pulse Sequence Accession Number: 23
;A. Bax, R.H. Griffey & B.L. Hawkins, J. Magn. Reson. 55, 301 (1983)


#include <Dmx.incl>

p2=p1*2
p4=p3*2
d4=2.3m
d3=2.7m

1 ze 
2 d11 do:f2
3 d11
4 4u
  d12 pl9:f1
  d1 cw:f1
  d13 do:f1
  d12 pl1:f1
  p1 ph1
  d4 pl2:f2                  ;reduced from 1/4J for proton T2
  (p4 ph1):f2 (p2 ph1)
  d4 
  p7 ph1
  (p1 ph3) (p3 ph2):f2
  d3                        ;  1/4J exactly
  (p4 ph1):f2 (p2 ph1)
  d3
  d12 pl11:f2
8 d13
  (p15 ph2):f2
  d13
  lo to 8 times l8
  d0
  p2 ph1
  d0
  d3 pl2:f2
  (p4 ph1):f2 (p2 ph1)
  d3
  (p1 ph5) (p3 ph4):f2
  d4
  (p2 ph1) (p4 ph1):f2
  d4 pl12:f2
  p7*1.3 ph1
  go=2 ph31 cpd2:f2 
  d11 do:f2 wr #0 if #0 ip2 zd
  lo to 3 times 2
  d11 id0 ip31*2
  lo to 4 times l3
exit 
  
  
ph2=0  
ph1=0 
ph3=1 3
ph4=0 0 2 2 
ph5=0 0 0 0 2 2 2 2
ph31=0 2 2 0 2 0 0 2


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p31:  - 90 degree pulse for decoupling sequence
;d0 : incremented delay (2D)                  [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d2 : 1/(2J)XH
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d13: short delay                                    [3 usec]
;L3: loop for phase sensitive 2D using States-TPPI method: l3 = td1/2
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 4 * n
;DS: 16
;td1: number of experiments
;MC2: States-TPPI
;cpd2: decoupling according to sequence defined by cpdprg2