remarks changed Mon Feb  3 18:05:35 WET 1997
 remarks bye jfd to include a physical bond to the Zn ion.
 remarks 

topology 
    @TOPPAR:Nilges/topallhdg.pro 
    @TOPPAR:top_zinc.pro
end

segment  name="A" 
    chain 
        @TOPPAR:Nilges/topallhdg.pep
        sequence
	    Phe Leu Glu Lys Ile
	    Glu Pro Ala Gln Glu
	    
	    Glu His Glu Lys Tyr
	    His Ser Asn Val Lys
	    
	    Glu Leu Ser His Lys
	    Phe Gly Ile Pro Asn
	    
	    Leu Val Ala Arg Gln
	    Ile Val Asn Ser Cys
	    
	    Ala Gln Cys Gln Gln
	    Lys
	end
    end
    chain 
         sequence zinc end
    end 
end



                              {* disulfide bridge  ...CYS - DISU - CYS...  *}
                              {* w/o the actual bond                       *}
patch DISN reference=1=( resid 40 )
	   reference=2=( resid 43 ) end

				 {* Patch to change doubly protonated HIS  *}

patch HISD reference=nil=( resid 12 ) end
patch HISE reference=nil=( resid 16 ) end

patch HISE reference=nil=( resid 24 ) end


							    {* C1   C2 *}
							    {*  \  /   *}
							    {*   Zn5   *}
							    {*  /  \   *}
							    {* H3   H4 *}
patch  ZINE
     reference=1=( resid 40 )
     reference=2=( resid 43 )
     reference=3=( resid 12 )
     reference=4=( resid 16 )
     reference=5=( resid 47 )
end

 write structure output=inem.psf end
 
 stop