;c13noe3d.fa
;3D (1H,13C,1H) NOESY-HSQC-SE with optional 15N decoupling
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: c13noe3d.gc,v 1.1 2021/02/11 14:49:08 bmrbsvc Exp $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm
;o3p: 43ppm
;
;p1 90 H at pl1
;p3 90 C at pl3
;d8 mixing time
;pl0 120dB
;
;C13 GARP decoupling (cpdprg3), pcpd 90 dgr pulse at pl13
; or WURST decoupling (cpdprg3), pcpd 90 dgr pulse at sp2 (define WURST below)
; For side-band suppression, define SBSUPR below (8 step phase cycle)
;N15 Waltz-16 (cpdprg2), pcpd 90 dgr pulse at pl12
;C evolution:
;  in0, SW(C)=1/(2*in0), typically 24ppm
;  l4 complex points
;  Define C_90180 below for DW/2 initial delay (90,-180 phase)
;  Process as Echo/Anti-Echo
;H1 evolution:
;  in10, SW(H)=1/(2*in10), typically 8ppm
;  set cnst10 to 0 (preferably) or 1 to make d10 the smallest possible
;  positive delay. cnst10=0 gives (90,-180) phase distortion in F1.
;  cnst10=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Processing: extend the FID backwards cnst10 points 
;  and apply (90,-180) phase correction
;  In addition a -45dgr phase correction is required (ph0).
;  l6 complex points
;  Process as States (although data is acquired as States-TPPI)
;
;ns=4*n (or 8*n if SBSUPR defined), ds=4, 8, ...
;
;Recommendations for gradients:
;gpz1:  12%
;gpz2:   7%
;gpz3:  24%
;gpz4:  29%
;gpx5:  54% adjust for magic angle
;gpz5:  30%
;gpz6:  24%
;gpz7:  15%
;gpx8:  54% adjust for magic angle
;gpz8:  30%
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.32
;gpnam4: sine.100
;gpnam5: sine.100
;gpnam6: sine.32
;gpnam7: sine.32
;gpnam8: sine.20
;
;#define ONE_D		; uncomment for 1D experiment
#define H1_EVOL		; comment out for 2D w/o H1 evolution
#define C13_EVOL	; comment out for 2D w/o C13 evolution
#define C_90180		; uncomment for an initial delay of dw/2 in t2 (C13)
#define N15_DEC		; uncomment for N15 decoupling
#define COMPOSITE	; uncomment for composite C13 180 pulses
;#define SBSUPR
;#define WURST
;#define MESSERLE
#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD8)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef C13_EVOL
#undef H1_EVOL
#endif
#ifndef C13_EVOL
#undef C_90180
#endif
;
define delay TAUA3
define delay TAUB6
define delay TAUA7
define delay TAUC
define delay DELTA
define delay CEN_HC1
define delay CEN_HC2
define pulse H1_90
define pulse H1_180
define pulse C13_90
define pulse C13_180
define pulse C13_59
define pulse C13_298
define pulse C13_240
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
;
"d11=100m"                      ;disk i/o
"d12=10u"                       ;power switching etc.
"d13=5u"                        ;a short delay
"d14=60u"			;ip,id etc.
"d16=300u"                      ;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"C13_90=p3"
"C13_180=C13_90*2"
"C13_59=C13_90*59.4/90.0"
"C13_240=C13_90*240.0/90.0"
"C13_298=C13_90*298.0/90.0"

"GRAD1=500u"
"GRAD2=1.0m"
"GRAD3=250u"
"GRAD4=1.0m"
"GRAD5=720u"
"GRAD6=250u"
"GRAD7=300u"
#ifndef OPTIM_P19
  "p19=181u"
#endif
"GRAD8=p19"

#ifdef C_90180
  "d0=d13+in0/2"
#else
  "d0=d13"
#endif
;"d2=1.866m"		;1/4J
;"d3=0.933m"		;1/8J
"d2=1.6m"		;1/4J
"d3=0.8m"		;1/8J
"d6=H1_90"
"d7=C13_90"
"TAUA3=d2-GRAD3-d13"
"TAUB6=d3-GRAD6-d13"
"TAUA7=d2-GRAD7-d13"
"TAUC=GRAD5+d16+d13-d13*2-H1_180"
#ifdef SBSUPR
  "DELTA=GRAD8+d16+d13*3+d12+C13_90*2"
#else
  "DELTA=GRAD8+d16+d13*2+d12"
#endif
"d18=d8-C13_90-d13-GRAD2-d16"
#ifdef H1_EVOL
  "d10=((cnst10*2+1)*in10-(H1_90*1.273+C13_90*4+d13*2))/2"
#endif

#ifdef COMPOSITE
"CEN_HC1=(C13_90*2+C13_180+d13*2-H1_180)/2"
"CEN_HC2=(C13_59*2+C13_298+d13*2-H1_180)/2"
#define INEPT_INV_X (CEN_HC1 H1_180 ph0):H (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
#define INEPT_INV_Y (CEN_HC1 H1_180 ph3):H (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
#define INEPT_REFOC (CEN_HC2 H1_180 ph0):H (C13_59 ph0 d13 C13_298 ph2 d13 C13_59 ph0):C
#else
"CEN_HC1=C13_90-H1_90"
#define INEPT_INV_X (CEN_HC1 H1_180 ph0):H (C13_180 ph0):C
#define INEPT_INV_Y (CEN_HC1 H1_180 ph3):H (C13_180 ph0):C
#define INEPT_REFOC (CEN_HC1 H1_180 ph0):H (C13_180 ph0):C
#endif

#ifdef EXPTCORR
  "d31=2*(TAUA3+GRAD6+TAUB6+GRAD7+TAUA7)+GRAD1+GRAD2+GRAD3+GRAD4+TAUC+GRAD5+DELTA+GRAD8"
#endif


#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13
  d14 do:C
  d11 LOCKH_OFF
  3m
  d14
3 d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl12:N pl3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  (C13_90 ph0):C
  d13
  GRAD1:gp1		; 500u, 8G/cm, sine.50
  d16
#ifdef N15_DEC
  d13 cpd2:N
#endif
#ifdef H1_EVOL
  (H1_90 ph5):H
  d10
  (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
  d10
#else
  (H1_90 ph4):H
  d13
#endif
  (H1_90 ph0):H
#ifdef N15_DEC
  d13 do:N
#endif
  d18
  (C13_90 ph0):C
  d13
  GRAD2:gp2		;1m, 5G/cm, sine.100
  d16
  (H1_90 ph0):H
  d13
  GRAD3:gp3		;250u, 16G/cm, sine.32
  TAUA3
  INEPT_INV_X
  d13
  GRAD3:gp3		;250u, 16G/cm, sine.32
  TAUA3
#ifdef MESSERLE
  (H1_90*55 ph0):H
  d13
#endif
  (H1_90 ph1):H
  d13
  GRAD4:gp4		;1m, 20G/cm, sine.100
;#ifdef N15_DEC
;  d16 cpd2:N
;#else
  d16
;#endif
  (C13_90 ph7):C
  d0 
  (H1_180 ph0):H
  d0 
;#ifdef N15_DEC
;  TAUC do:N
;#else
  TAUC
;#endif
  (C13_180 ph0):C
  d13
  GRAD5:gp5*EA*-1	;720u, -/+40G/cm, sine.100
  d16
  (C13_90 ph8):C
  d6
  (H1_90 ph0):H
  d13
  GRAD6:gp6		;250u, 16G/cm, sine.32
  TAUB6
  (C13_180 ph0):C
  (H1_180 ph0):H 
  d13
  GRAD6:gp6		;250u, 16G/cm, sine.32
  TAUB6
  d7
  (C13_90 ph1):C
  (H1_90 ph1):H 
  d13
  GRAD7:gp7		;300u, 10G/cm, sine.32
  TAUA7                                                       
  INEPT_INV_X
  d13
  GRAD7:gp7		;300u, 10G/cm, sine.32
  TAUA7 
  (H1_90 ph0):H
  DELTA
  (H1_180 ph0):H
  d13
  GRAD8:gp8		;181u, 40G/cm, sine.20
  d13
  d16 BLKGRAMP

#ifdef SBSUPR
  (C13_90 ph0 d13 C13_90 ph13):C
#endif
#ifdef WURST
  d12 pl0:C
#else
  d12 pl13:C
#endif

  go=2 ph31 cpds3:C

#ifdef ONE_D
  d11 do:C wr #0
#else
  d11 do:C wr #0 if #0 zd
#endif
  d13 LOCKH_OFF
#ifdef C13_EVOL
  3m igrad EA
  d14 ip8
  d14 ip8
  lo to 3 times 2
  d14 id0
  d14 ip7
  d14 ip7
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd0
#endif
#ifdef H1_EVOL
  d14 ip5
  d14 ip5
  lo to 5 times 2
  d14 id10
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph4=0 2
ph5=(8) 1 5
ph7=0 0 2 2
ph8=0
ph13=0 0 0 0 2 2 2 2
ph31=0 2 2 0