;mlevphpr.2
;avance-version (12/01/11)
;homonuclear Hartman-Hahn transfer using MLEV17 sequence
;   for mixing
;using two power levels for excitation and spinlock
;phase sensitive
;only using first trim pulse
;
;A. Bax & D.G. Davis, J. Magn. Reson. 65, 355-360 (1985)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
;$RECOMMEND=y


#include <Avance.incl>
#include <Delay.incl>


"p5=p6*.667"
"p7=p6*2"
"d11=30m"
"d12=20u"
"d13=4u"


"in0=inf1"

"d0=in0/2-p1*2/3.1416-4u"


"SCALEF=p7*2/p5"
"FACTOR1=((d9-p17)/(p6*64+p5))/SCALEF"
"l1=FACTOR1*SCALEF"


"acqt0=0"


1 ze
2 d11
3 d12 pl9:f1
  d1 cw:f1 ph29
  d13 do:f1
  d12 pl1:f1
  p1 ph1
  d0
  4u pl10:f1
  (p17 ph26)
						;begin MLEV17
4 (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph24 p7 ph25 p6 ph24)
  (p5 ph23)
  lo to 4 times l1 
						;end MLEV17
  go=2 ph31
  d11 mc #0 to 2 F1PH(calph(ph1, +90) & calph(ph29, +90), caldel(d0, +in0))
exit


ph1=0 2 2 0 1 3 3 1
ph22=3 1 3 1 0 2 0 2
ph23=0 2 0 2 1 3 1 3
ph24=1 3 1 3 2 0 2 0
ph25=2 0 2 0 3 1 3 1
ph26=0 2 0 2 1 3 1 3
ph29=0
ph31=0 2 2 0 1 3 3 1


;pl1 : f1 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;pl10: f1 channel - power level for TOCSY-spinlock
;p1 : f1 channel -  90 degree high power pulse
;p5 : f1 channel -  60 degree low power pulse
;p6 : f1 channel -  90 degree low power pulse
;p7 : f1 channel - 180 degree low power pulse
;p17: f1 channel - trim pulse                        [2.5 msec]
;d0 : incremented delay (2D)
;d1 : relaxation delay; 1-5 * T1
;d9 : TOCSY mixing time
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d13: short delay                                    [4 usec]
;l1: loop for MLEV cycle: (((p6*64) + p5) * l1) + (p17) = mixing time
;inf1: 1/SW = 2 * DW
;in0: 1/(1 * SW) = 2 * DW
;nd0: 1
;ns: 8 * n
;ds: 16
;td1: number of experiments
;FnMODE: States-TPPI, TPPI, States or QSEQ


;Processing

;PHC0(F1): 180
;PHC1(F1): -180
;FCOR(F1): 1



;$Id: mlevphpr.2,v 1.13 2012/01/31 17:49:27 ber Exp $
