;noesyhsqcetf3gp3d
;avance-version (20/03/03)
;NOESY-HSQC
;3D sequence with
;   homonuclear correlation via dipolar coupling 
;   dipolar coupling may be due to noe or chemical exchange.
;   H-1/X correlation via double inept transfer
;phase sensitive (t1)
;phase sensitive using Echo/Antiecho-TPPI gradient selection (t2)
;using trim pulses in inept transfer
;with decoupling during acquisition
;(use parameterset NOESYHSQCETF3GP3D)
;
;A.L. Davis, J. Keeler, E.D. Laue & D. Moskau, J. Magn. Reson. 98, 
;   207-216 (1992)
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"p22=p21*2"
"d11=30m"
"d12=20u"
"d26=1s/(cnst4*4)"


"d0=3u"
"d10=3u"

"in0=inf1/2"
"in10=inf2/2"


"DELTA2=d26-p16-8u"

#   ifdef LABEL_CN
"DELTA=larger(p14,p22)+d0*2"
"DELTA1=p16+d16+larger(p2,p14)+d10*2"
#   else
"DELTA=p22+d0*2"
"DELTA1=p16+d16+p2+d10*2"
#   endif /*LABEL_CN*/


aqseq 321


1 ze
  d11 pl16:f3
2 d1 do:f3
3 d12 pl3:f3
  (p1 ph7)
  DELTA
  (p2 ph8)
  d0

#   ifdef LABEL_CN
  (center (p14:sp3 ph1):f2 (p22 ph1):f3 )
#   else
  (p22 ph1):f3
#   endif /*LABEL_CN*/

  d0
  (p1 ph1):f1
  d8
  (p1 ph1):f1
  d26
  (center (p2 ph1) (p22 ph6):f3 )
  d26 UNBLKGRAD

#   ifdef TRIMP
  p28 ph1
#   endif /* TRIMP */

  (p1 ph2) (p21 ph3):f3
  d10 

#   ifdef LABEL_CN
  (center (p2 ph5) (p14:sp3 ph1):f2 )
#   else
  (p2 ph5)
#   endif /*LABEL_CN*/

  d10
  p16:gp1*EA
  d16
  (p22 ph4):f3
  DELTA1
  (ralign (p1 ph1) (p21 ph4):f3 )
  d26
  (center (p2 ph1) (p22 ph1):f3 )
  4u
  p16:gp2
  DELTA2 pl16:f3
  4u BLKGRAD
  go=2 ph31 cpd3:f3
  d1 do:f3 mc #0 to 2 
     F1PH(calph(ph7, +90) & calph(ph8, +90), caldel(d0, +in0)) 
     F2EA(calgrad(EA), caldel(d10, +in10) & calph(ph3, +180) & calph(ph6, +180) & calph(ph31, +180))
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph5=0 0 2 2
ph6=0
ph7=0 0 0 0 2 2 2 2
ph8=1 1 1 1 3 3 3 3
ph31=0 2 0 2 2 0 2 0 2 0 2 0 0 2 0 2
  

;pl1 : f1 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl16: f3 channel - power level for CPD/BB decoupling
;sp3: f2 channel - shaped pulse 180 degree (adiabatic)
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p14: f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;p16: homospoil/gradient pulse
;p21: f3 channel -  90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p28: f1 channel - trim pulse
;d0 : incremented delay (F1 in 3D)                     [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d10: incremented delay (F2 in 3D)                     [3 usec]
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J)YH
;cnst4: = J(YH)
;inf1: 1/SW(H) = 2 * DW(H)
;inf2: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(H)) = DW(H)
;nd0: 2
;in10: 1/(2 * SW(X)) = DW(X)
;nd10: 2
;ns: 8 * n
;ds: >= 16
;td1: number of experiments in F1
;td2: number of experiments in F2
;FnMODE: States-TPPI (or TPPI) in F1
;FnMODE: echo-antiecho in F2
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence


;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13, 8.1% for N-15

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100


                                          ;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with 
;             option -DLABEL_CN (eda: ZGOPTNS)
;TRIMP: to use trimpulse p28@pl1 start experiment with
;          option -DTRIMP (eda: ZGOPTNS)
                                          ;preprocessor-flags-end


;for older datasets use AQORDER : 3 - 2 - 1



;$Id:$
