#include "bits.gc"
; used for caha J and RDCs measurements (antiphase coupled spectra)
;xcorrca1.abx  adapted from cbcaconh.sg  (ATTENUATED)
; to measure Ca CSA from interference
;sg 1/28/92
;changed to DMX 12/30/95 modified 11/29/96
;changed to hcaconX-ge.nt 4/14/97 NT

;DS=(2n+1)*NS, i.e. ns, 3ns, 5ns ... Don't use DS=0 !!!!

;f1 = hydrogen frequency on water
;p1=proton hard 90 
;pcpd1 90 (64u) at pl30 ~ 13dB waltz16 decoupling power cpds1

;p3 90 CA pulse, 23.7u pl3 (@600); 28.6u @ 2.2dB @500; 19.2@750
;p4 90 CA pulse, 53.0u pl4 (@600); 64.8u @ 9.3dB @500; 42.4@750
;set pl8 to 120dB !
;p6 CO sinc1.0 150u (@750) 90 at sp1 ~12dB spoffs1=121ppm  ; 220u @500
;p14 90 CA pulse, 19.2@750 @pl14 ; 28.6u @ 2.2dB @500
;p15 hsec.3 500u CA 180 at sp3 ; replaced with reburp.256 280u -3.8dB 
;p16 sinc1.0 150u (@750) CO 180 at sp0 ; 220 @ ~9.44dB fasinc.256 @500, spoffs0=121ppm
;p16 sinc1.0 150u (@750) CA 180 at sp2 ; 220 @ ~9.44dB fasinc.256 @500 

;nitrogen
;p2 = high power nitrogen 90 
;pcpd2 = low power 90 pulse 200us at pl31 waltz16 cpd2 (262u @9dB @500)

;******	CA/CB evolution	******

;in18=in19=1/(2sw); CLOOPmax=d19/in19+1 (=65 for in19=195u @ 600)


;******	N evolution	******
;in27=in29=1/(2sw) ; NLOOPmax=d27/in27+1 (=66 for in27=228u @ 600)


#define NITRO
#define C_ALPHA
#define CRP        ; uncomment for use on CryoProbe (no sim. N15,C13 pulses)

define loopcounter NLOOP
define loopcounter CLOOP

"NLOOP=60"   ; for 600, ~27 ms AQ
"CLOOP=65"   ; for 600, ~25 ms AQ, use max, resolution needed! 


"d30=2.0m"	;N to HN transfer time

"d21=p2-p1"
"d22=p16" ; 190u @600
"d24=p16*0.5-p2"
"d25=p16*0.5-p1"


"d29=10u"
"d27=15m"
"d28=d27-d29-p16-3.4m" ;p16=150us
"d26=d27-d29-d30-3.4m" ;d26<d28!
"d23=d26-p2*2"
"d31=13m-p2*2"

"d13=p1*2.0"
"d14=p14*2.0"

"d5=20u"	;universal dd, id, ip delay
"d11=50m"

;-------------- Gradient pulses -----------------
#define GRAD19(ampl) p19:ngrad:c34
#define GRAD20(ampl) p20:ngrad:c34
#define GRAD21(ampl) p21:ngrad:c34
#define GRAD22(ampl) p22:ngrad:c34
#define GRAD23(ampl) p23:ngrad:c34
#define GRAD24(ampl) p24:ngrad:c34
#define GRAD25(ampl) p25:ngrad:c34
#define GRAD26(ampl) p26:ngrad:c34
#define GRAD27(ampl) p27:ngrad:c34

;you have to set them by hand (also cnst 20,21,24,25,26,27)
"p19=4.0m"
"p20=2.0m"
"p21=1.0m"
"p22=1.2m"
"p23=1.1m"
"p24=0.20m"
"p25=74us" ;optimized @600i for max signal
"p26=2.705m"
"p27=2.1m"

"d3=2.65m-p22"
"d4=2.65m-p23"
"d6=3.4m-p26"
"d15=0.25m-p24"
"d16=0.25m-p25"

"d18 = 4u"				;set back to 4u
;"d18 = 4u +1.8m"			;for S/N test only!
"d19 = 12.423m +d18 +d22"		;set back to 12.423m
;"d19 = 12.423m +d18 +d22 -1.8m"	;for S/N test only!

;******	end declaration	******

	ze
2	5u do:N
	d11
	d5
7	d5*4 do:N
8	d5*2 do:N
9	d5*4 do:N
10	10u do:N
;*******;	presaturation		*******
	10u LOCK_ON
	50m pl1:H
	50u pl3:C
	50u pl2:N
	d1                          ;fq1:H
	(p3 ph0):C		;get rid of boltzman
	2u
	(p2 ph0):N
	2u
	GRAD19(cnst21)          ;p19=4m, 
	2.5m
	10u LOCK_OFF
;*******	start 90-degree on ha/hb*******
	(p1 ph0):H
	1.4m
	(p3*2 ph0):C (p1*2 ph1):H
	1.4m
	(p1 ph3):H 
	4u
	GRAD20(cnst21)
	0.5m pl4:C
#ifdef CRP
	0.5m pl2:N
	10u ;cpd2:N
#else
	0.5m pl31:N
	10u cpd2:N
#endif
;*******	inept to c aliphatic	*******
	(p4 ph0):C
	2u
	3u pl8:C
	(p15:sp3 ph0):C
	4u
	4.6m		;changed from 5.5m
	d18 pl8:C
        (p16:sp0 ph10):C
;       (d25 p1*2 ph0):f1 (p16:sp0 ph10):f4
        2u
	GRAD21(cnst21)
	7.9m pl8:C	;changed from 7.0m
	(p15:sp3 ph13):C
	2u
	GRAD21(cnst21)
	d19 pl30:H
	9u pl4:C
	(p4 ph6):C
	2u
	GRAD27(cnst21)
	0.5m do:N
	0.5m pl30:H
	10u pl8:C
	10u cpds1:H
;*******	inept to carbonyl	*******
	(p6:sp1 ph7):C
	4.5m pl14:C
	(p14*2 ph8):C	;offset rect 180 on CA (-121 ppm)
	5.5m pl2:N
	3m pl8:C
#ifdef CRP
	(p16:sp0 ph0):C (d24 p2*2 ph0):N
	13m pl8:C
;	(p16:sp0 ph0):C 
;	(p2*2 ph0):N
;	d31 pl8:C
#else
	(p16:sp0 ph0):C (d24 p2*2 ph0):N
	13m pl8:C
#endif
	d14 pl8:C		;comp for p4*2
	(p6:sp1 ph11):C
;*******	inept to nitrogen	*******
	(p2 ph0):N
	d27
#ifdef CRP
	(p16:sp0 ph10):C (d24 p2*2 ph12):N
	(d26 d29 d30 do):H (d28 p16:sp2 ph10 d29):C
;	(p2*2 ph12):N
;	(p16:sp0 ph10):C 
;	(d23 d29 d30 do):H (d28 p16:sp2 ph10 d29):C
#else
	(p16:sp0 ph10):C (d24 p2*2 ph12):N
	(d26 d29 d30 do):H (d28 p16:sp2 ph10 d29):C
#endif
	GRAD26(cnst26)
	d6 pl1:H
;*******	inept to protons	*******
	(d21 p1 ph0):H (p2 ph9):N
	2u
	GRAD22(cnst20)
	d3
	(d21 p1*2 ph0):H (p2*2 ph0):N
	2u
	GRAD22(cnst20)
	d3
	(p1 ph1):H (p2 ph1):N
	2u
	GRAD23(cnst20)
	d4
	(d21 p1*2 ph0):H (p2*2 ph0):N
	2u
	GRAD23(cnst20)
	d4
	(d21 p1 ph0):H
	4u
	GRAD24(cnst24)
	d15
	(p1*2 ph0):H
	2u
	GRAD25(cnst25)
	d16 pl31:N
	(2u ph0)
go=2 ph31 cpd2:N
5u do:N
d11 wr #0 if #0 zd

#ifdef NITRO
d5*0.5 ip9
d5*0.5 ip9
lo to 7 times 2
d5*2.0 dd27
d5*2.0 id29
lo to 8 times NLOOP
d5*0.5 rd27
d5*0.5 rd29
#endif

#ifdef C_ALPHA
d5 ip6
lo to 9 times 2
d5 id18
d5 dd19
d5 ip31
d5 ip31
lo to 10 times CLOOP
#endif
10u LOCK_ON
10u do:N
exit

ph0=0
ph1=1
ph3=1 1 1 1 3 3 3 3 
ph2=0
ph6=0 0 2 2
ph7=0 2
ph8=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph9=0 
ph10=0
ph11=(360)20	;adjusted for BS compensation
ph12=0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph13=(360)7		;BS compensation
ph31=0 2 2 0